MODIFIED GRAMMAR, FIRST SETS AND FOLLOW SETS

**MODIFIED GRAMMAR**

<program> ===> <otherFunctions> <mainFunction>

<mainFunction> ===> TK\_MAIN <stmts> TK\_END

<otherFunctions> ===> <function> <otherFunctions> | eps

<function> ===> TK\_FUNID <input\_par> <output\_par> TK\_SEM <stmts> TK\_END

<input\_par> ===> TK\_INPUT TK\_PARAMETER TK\_LIST TK\_SQL <parameter\_list> TK\_SQR

<output\_par> ===> TK\_OUTPUT TK\_PARAMETER TK\_LIST TK\_SQL <parameter\_list> TK\_SQR | eps

<parameter\_list> ===> <dataType> TK\_ID <remaining\_list>

<dataType> ===> <primitiveDatatype> | <constructedDatatype>

<primitiveDatatype> ===> TK\_INT | TK\_REAL

<constructedDatatype> ===> TK\_RECORD TK\_RECORDID

<remaining\_list> ===> TK\_COMMA <parameter\_list> | eps

<stmts> ===> <typeDefinitions> <declarations> <otherStmts> <returnStmt>

<typeDefinitions> ===> <typeDefinition> <typeDefinitions> | eps

<typeDefinition> ===> TK\_RECORD TK\_RECORDID <fieldDefinitions> TK\_ENDRECORD TK\_SEM

<fieldDefinitions> ===> <fieldDefinition> <fieldDefinition> <moreFields>

<fieldDefinition> ===> TK\_TYPE <primitiveDatatype> TK\_COLON TK\_FIELDID TK\_SEM

<moreFields> ===> <fieldDefinition> <moreFields> | eps

<declarations> ===> <declaration> <declarations> | eps

<declaration> ===> TK\_TYPE <dataType> TK\_COLON TK\_ID TK\_COLON <global\_or\_not> TK\_SEM

<global\_or\_not> ===> TK\_GLOBAL | eps

<otherStmts> ===> <stmt> <otherStmts> | eps

<stmt> ===> <assignmentStmt> | <iterativeStmt> | <conditionalStmt> | <ioStmt> | <funCallStmt>

<assignmentStmt> ===> <singleOrRecId> TK\_ASSIGNOP <arithmeticExpression> TK\_SEM

<singleOrRecId> ===> TK\_ID | TK\_RECORDID TK\_DOT TK\_FIELDID

<funCallStmt> ===> <outputParameters> TK\_CALL TK\_FUNID TK\_WITH TK\_PARAMETERS <inputParameters>

<outputParameters> ===> TK\_SQL <idList> TK\_SQR TK\_ASSIGNOP | eps

<inputParameters> ===> TK\_SQL <idList> TK\_SQR

<iterativeStmt> ===> TK\_WHILE TK\_OP <booleanExpression> TK\_CL <stmt> <otherStmts> TK\_ENDWHILE

<conditionalStmt> ===> TK\_IF <booleanExpression> TK\_THEN <stmt> <otherStmts> <conditionalSuffix>

<conditionalSuffix> ===> TK\_ELSE <otherStmts> TK\_ENDIF | TK\_ENDIF

<ioStmt> ===> TK\_READ TK\_OP <allVar> TK\_CL TK\_SEM | TK\_WRITE TK\_OP <allVar> TK\_CL TK\_SEM

<allVar> ===> <var> | TK\_RECORDID

<arithmeticExpression> ===> <arithmeticT> <arithmeticE1>

<arithmeticE1> ===> <operator\_plusMinus> <arithmeticT> <arithmeticE1> | eps

<arithmeticT> ===> <arithmeticF> <arithmeticT1>

<arithmeticT1> ===> <operator\_mulDiv> <arithmeticF> <arithmeticT1> | eps

<arithmeticF> ===> TK\_OP <arithmeticExpression> TK\_CL | <var>

<operator\_plusMinus> ===> TK\_PLUS | TK\_MINUS

<operator\_mulDiv> ===> TK\_MUL | TK\_DIV

<booleanExpression> ===> TK\_OP <booleanExpression> TK\_CL <logicalOp> TK\_OP <booleanExpression> TK\_CL | <var> <relationalOp> <var> | TK\_NOT <booleanExpression>

<var> ===> TK\_ID | TK\_NUM | TK\_RNUM

<logicalOp> ===> TK\_AND | TK\_OR

<relationalOp> ===> TK\_LT | TK\_LE | TK\_EQ | TK\_GT | TK\_GE | TK\_NE

<returnStmt> ===> TK\_RETURN <optionalReturn> TK\_SEM

<optionalReturn> ===> TK\_SQL <idList> TK\_SQR | eps

<idList> ===> TK\_ID <more\_ids>

<more\_ids> ===> TK\_COMMA <idList> | eps

**FIRST SETS**

<program> ===> {TK\_FUNID, TK\_MAIN}

<mainFunction> ===> {TK\_MAIN}

<otherFunctions> ===> {TK\_FUNID, eps}

<function> ===> {TK\_FUNID}

<input\_par> ===> {TK\_INPUT}

<output\_par> ===> {TK\_OUTPUT, eps}

<parameter\_list> ===> {TK\_INT, TK\_REAL, TK\_RECORD}

<dataType> ===> {TK\_INT, TK\_REAL, TK\_RECORD}

<primitiveDatatype> ===> {TK\_INT, TK\_REAL}

<constructedDatatype> ===> {TK\_RECORD}

<remaining\_list> ===> {TK\_COMMA, eps}

<stmts> ===> {TK\_RECORD, TK\_ID, TK\_SQL, TK\_TYPE, TK\_RECORDID, TK\_WHILE, TK\_CALL, TK\_IF, TK\_READ, TK\_WRITE, TK\_RETURN}

<typeDefinitions> ===> {TK\_RECORD, eps}

<typeDefinition> ===> {TK\_RECORD}

<fieldDefinitions> ===> {TK\_TYPE}

<fieldDefinition> ===> {TK\_TYPE}

<moreFields> ===> {TK\_TYPE, eps}

<declarations> ===> {TK\_TYPE, eps}

<declaration> ===> {TK\_TYPE}

<global\_or\_not> ===> {TK\_GLOBAL, eps}

<otherStmts> ===> {TK\_ID, TK\_SQL, TK\_RECORDID, TK\_WHILE, TK\_CALL, TK\_IF, TK\_READ, TK\_WRITE, eps}

<stmt> ===> {TK\_ID, TK\_SQL, TK\_RECORDID, TK\_WHILE, TK\_CALL, TK\_IF, TK\_READ, TK\_WRITE}

<assignmentStmt> ===> {TK\_ID, TK\_RECORDID}

<singleOrRecId> ===> {TK\_ID, TK\_RECORDID}

<funCallStmt> ===> {TK\_SQL, TK\_CALL}

<inputParameters> ===> {TK\_SQL}

<outputParameters> ===> {TK\_SQL, eps}

<iterativeStmt> ===> {TK\_WHILE}

<conditionalStmt> ===> {TK\_IF}

<conditionalSuffix> ===> {TK\_ELSE, TK\_ENDIF}

<ioStmt> ===> {TK\_READ, TK\_WRITE}

<allVar> ===> {TK\_ID, TK\_NUM, TK\_RECORDID, TK\_RNUM}

<arithmeticExpression> ===> {TK\_OP, TK\_ID, TK\_NUM, TK\_RNUM}

<arithmeticE1> ===> {TK\_PLUS, TK\_MINUS, eps}

<arithmeticT> ===> {TK\_OP, TK\_ID, TK\_NUM, TK\_RNUM}

<arithmeticT1> ===> {TK\_MUL, TK\_DIV, eps}

<arithmeticF> ===> {TK\_OP, TK\_ID, TK\_NUM, TK\_RNUM}

<operator\_plusMinus> ===> {TK\_PLUS, TK\_MINUS}

<operator\_mulDiv> ===> {TK\_MUL, TK\_DIV}

<booleanExpression> ===> {TK\_OP, TK\_ID, TK\_NUM, TK\_NOT, TK\_RNUM}

<var> ===> {TK\_ID, TK\_NUM, TK\_RNUM}

<logicalOp> ===> {TK\_AND, TK\_OR}

<relationalOp> ===> {TK\_LT, TK\_LE, TK\_EQ, TK\_GT, TK\_GE, TK\_NE}

<returnStmt> ===> {TK\_RETURN}

<optionalReturn> ===> {TK\_SQL, eps}

<idList> ===> {TK\_ID}

<more\_ids> ===> {TK\_COMMA, eps}

**FOLLOW SETS**

<program> ===> {$}

<mainFunction> ===> {$}

<otherFunctions> ===> {TK\_MAIN}

<function> ===> {TK\_MAIN, TK\_FUNID}

<input\_par> ===> {TK\_OUTPUT, TK\_SEM}

<output\_par> ===> {TK\_SEM}

<parameter\_list> ===> {TK\_SQR}

<dataType> ===> {TK\_ID, TK\_COLON}

<primitiveDatatype> ===> {TK\_ID, TK\_COLON}

<constructedDatatype> ===> {TK\_ID, TK\_COLON}

<remaining\_list> ===> {TK\_SQR}

<stmts> ===> {TK\_END}

<typeDefinitions> ===> {TK\_TYPE, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL, TK\_RETURN}

<typeDefinition> ===> {TK\_RECORD, TK\_TYPE, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL, TK\_RETURN}

<fieldDefinitions> ===> {TK\_ENDRECORD}

<fieldDefinition> ===> {TK\_TYPE, TK\_ENDRECORD}

<moreFields> ===> {TK\_ENDRECORD}

<declarations> ===> {TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL, TK\_RETURN}

<declaration> ===> {TK\_TYPE, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL, TK\_RETURN}

<global\_or\_not> ===> {TK\_SEM}

<otherStmts> ===> {TK\_RETURN, TK\_ENDWHILE, TK\_ELSE, TK\_ENDIF}

<stmt> ===> {TK\_RETURN, TK\_ENDWHILE, TK\_ELSE, TK\_ENDIF, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL}

<assignmentStmt> ===> {TK\_RETURN, TK\_ENDWHILE, TK\_ELSE, TK\_ENDIF, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL}

<singleOrRecId> ===> {TK\_ASSIGNOP}

<funCallStmt> ===> {TK\_RETURN, TK\_ENDWHILE, TK\_ELSE, TK\_ENDIF, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL}

<outputParameters> ===> {TK\_CALL}

<inputParameters> ===> {TK\_RETURN, TK\_ENDWHILE, TK\_ELSE, TK\_ENDIF, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL}

<iterativeStmt> ===> {TK\_RETURN, TK\_ENDWHILE, TK\_ELSE, TK\_ENDIF, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL}

<conditionalStmt> ===> {TK\_RETURN, TK\_ENDWHILE, TK\_ELSE, TK\_ENDIF, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL}

<conditionalSuffix> ===> {TK\_RETURN, TK\_ENDWHILE, TK\_ELSE, TK\_ENDIF, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL}

<ioStmt> ===> {TK\_RETURN, TK\_ENDWHILE, TK\_ELSE, TK\_ENDIF, TK\_ID, TK\_RECORDID, TK\_WHILE, TK\_IF, TK\_READ, TK\_WRITE, TK\_SQL, TK\_CALL}

<allVar> ===> {TK\_CL}

<arithmeticExpression> ===> {TK\_CL, TK\_SEM}

<arithmeticE1> ===> {TK\_CL, TK\_SEM}

<arithmeticT> ===> {TK\_PLUS, TK\_MINUS, TK\_CL, TK\_SEM}

<arithmeticT1> ===> {TK\_PLUS, TK\_MINUS, TK\_CL, TK\_SEM}

<arithmeticF> ===> {TK\_MUL, TK\_DIV, TK\_PLUS, TK\_MINUS, TK\_CL, TK\_SEM}

<operator\_plusMinus> ===> {TK\_OP, TK\_ID, TK\_NUM, TK\_RNUM}

<operator\_mulDiv> ===> {TK\_OP, TK\_ID, TK\_NUM, TK\_RNUM}

<booleanExpression> ===> {TK\_CL, TK\_THEN}

<var> ===> {TK\_LT, TK\_LE, TK\_EQ, TK\_GT, TK\_GE, TK\_NE, TK\_CL, TK\_THEN, TK\_PLUS, TK\_MUL, TK\_MINUS, TK\_DIV, TK\_SEM}

<logicalOp> ===> {TK\_OP}

<relationalOp> ===> {TK\_ID, TK\_NUM, TK\_RNUM}

<returnStmt> ===> {TK\_END}

<optionalReturn> ===> {TK\_SEM}

<idList> ===> {TK\_SQR}

<more\_ids> ===> {TK\_SQR}